Как отобразить дату в другом формате

[Матвей Н]

Привет!
Помогите, пожалуйста! Из командной строки WinXP нужно создать файл с именем, равным текущей дате и расширением "txt". Но дата в имени должна быть в формате ГГГГ-ММ-ДД. Я сделал такой cmd-файл:

@ECHO off
ECHO Test > %Date%.txt

При запуске создается текстовый файл с содержимым "Test" и именем 29.04.2008.txt
А мне нужно: 2008-04-29.txt
Я так понимаю, что формат даты у меня на машине именно дд.мм.гггг.
Подскажите, как можно преобразовать имя файла, не меняя формата даты на машине?

[5c00p]

Командами ОС этого сделать нельзя.

Я когда-то сталкивался с похожей задачей. Мне надо было создавать архивные файлы в автоматическом режиме с именами, содержащими дату и время. Но с архивами проще: при помощи WinRAR это сделать легко сделать.

[avk2567]

Можно так:

@echo off
FOR /F "TOKENS=1,2,3 delims=. " %%k IN ('DATE /T') DO @echo Test > %%m-%%l-%%k.txt

[5c00p]

Действительно.

Но у меня заработало только вот так:

FOR /F "TOKENS=1,2,3 delims=. " %k IN ('DATE /T') DO @echo Test > %m-%l-%k.txt

т.е. с 1 символом %.

[avk2567]

В командной строке работает с одним (%) , в .bat-е с двумя (%%).

[Black_Swamp]

А почему с k начал? можно с а
FOR /F "TOKENS=1,2,3 delims=. " %a IN ('DATE /T') DO @echo Test > %c.%b.%a.txt
Начало алфавита всё таки :D

[Матвей Н]

Спасибо большое всем! Но аппетит приходит во время еды ))
Возник новый вопрос:
А если я хочу получить в имени файла вчерашнюю дату, то как в этом случае быть? Интуиция подсказывает, что простой "FOR" тут уже не поможет.

[avk2567]

Посмотри здесь

Под вопросом <Q:How do I perform calculations?> будет ответ.

[Black_Swamp]

Ничего не понял по ссылке данной выше, как не пробовал ничего не получилось, можно вручную, но тут условие такое, обязательно ввести какое нибудь число, и надо чтобы это находилось в файле *.bat

@echo off
set /p a= Введите число от 1 до 31: 
if %a% LSS 32 (goto first) ELSE goto second
:first
FOR /F "TOKENS=1,2,3 delims=. " %%a IN ('DATE /T') DO echo Test > %%c.%%b.%a%.txt
exit
:second
FOR /F "TOKENS=1,2,3 delims=. " %%a IN ('DATE /T') DO echo Test > %%c.%%b.%%a.txt
exit

[avk2567]

Передранное и малость переделанное оттуда-же
bat файл:
foo.bat

@echo off

set $tok=1-3
for /f "tokens=1 delims=.:/-, " %%u in ('date /t') do set $d1=%%u
if "%$d1:~0,1%" GTR "9" set $tok=2-4
for /f "tokens=%$tok% delims=.:/-, " %%u in ('date /t') do (
for /f "skip=1 tokens=2-4 delims=/-,()." %%x in ('echo.^|date') do (
set %%x=%%u
set %%y=%%v
set %%z=%%w
set $d1=
set $tok=))

::Force non-leading zero, as it may cause failure
set /a PDDD=1%DD% - 101
set /a PDMM=1%MM% - 100
set /a PDYY=%YY%
if %PDDD% GTR 0 goto return
set /a PDMM=%PDMM% - 1
if %PDMM% GTR 0 goto isleap
set /a PDDD=31
set /a PDMM=12
set /a PDYY=%PDYY% - 1
goto return
:isleap
if not %PDMM% EQU 2 goto days%PDMM%
::Temporarily use PDDD as a work field
set /a PDDD=%PDYY% / 4
set /a PDDD=%PDDD% * 4
if %PDDD% EQU %PDYY% goto leap
set /a PDDD=28
goto return
:leap
set /a PDDD=29
goto return
:days1
:days3
:days5
:days7
:days8
:days10
set /a PDDD=31
goto return
:days4
:days6
:days9
:days11
set /a PDDD=30
:return
::Force leading zero when day or month is single digit
set /a PDDD=%PDDD% + 100
set PDDD=%PDDD:~1,2%
set /a PDMM=%PDMM% + 100
set PDMM=%PDMM:~1,2%

в конечнои итоге DD,MM,YY устанавливются соотвественно сегодняшней дате ,а PDDD, PDMM, PDYY - вчерашнему дню. Что с этими переменными делать дальше - дело хозяйское

[Матвей Н]

О, классно! А Вы разобрались, что означают эти строки?

Цитата: Сообщение от avk2567 set PDDD=%PDDD:~1,2%

Я долго пыжился над параметрами после двоеточия ) Подбирал и так, и сяк. А потом осенило: это ж аналог MID в Бейсике! После "тильды" стоит количество отбрасываемых символов строки, а после "запятой" количество символов, которое затем нужно взять.
В связи с этим у меня родилась идея для второго варианта решения моей первой проблемы:
Второй вариант первой проблемы

@echo off
:: Вот наша дата 01.05.2008 - переменная среды %DATE%

:: Берем два первых символа из строки даты (01) - это день
set zd=%date:~,2%

:: Отбрасываем 3 символа даты (01.) и берем два (05) - это месяц
set zm=%date:~3,2%

:: Отбрасываем 6 символов даты (01.05.) и берем четыре (2008) - это год
set zy=%date:~6,4%

echo test > %zy%-%zm%-%zd%.txt

[vmunt]

Цитата: Сообщение от Матвей Н Второй вариант первой проблемы

Прикольно! Или ещё короче:
Test >%date:~6,4%.%date:~3,2%.%date:~0,2%.txt

Добавлено через 2 минуты
Тьфу! Echo пропало! Надо так:
echo Test >%date:~6,4%.%date:~3,2%.%date:~0,2%.txt

[avk2567]

Цимес то в том, что сей кусок

@echo off
set $tok=1-3
for /f "tokens=1 delims=.:/-, " %%u in ('date /t') do set $d1=%%u
if "%$d1:~0,1%" GTR "9" set $tok=2-4
for /f "tokens=%$tok% delims=.:/-, " %%u in ('date /t') do (
for /f "skip=1 tokens=2-4 delims=/-,()." %%x in ('echo.^|date') do (
set %%x=%%u
set %%y=%%v
set %%z=%%w
set $d1=
set $tok=))

уставливает переменные dd,mm,yy корректно, независимо от текущих региональных установок!

[Матвей Н]

А как понять эту запись?

Цитата: Сообщение от avk2567 set $tok=1-3

Что такое $tok - произвольная переменная среды или "$" что-то значит?

Тем не менее, вдохновившись полученными достижениями в области числовых операций и обработки строк )) я решил обобщить вторую задачку и написал батничек, который к любой дате прибавляет (или вычитает) любое количество дней и возвращает полученную дату. Батник - ниже на Ваш суд.
addday.cmd

:: ************************************************
:: * Увеличение/уменьшение даты
:: * Параметры:
:: * %1 - Дата в формате дд.мм.гггг, например, 02.05.2008
:: * %2 - Сдвиг в днях (вперед с "+", назад с "-"), например, +600 или -132
:: * Результат - новая дата.
:: * Ограничение. Год не может быть меньше 2000 (так, для простоты).
:: ************************************************

@echo off
set zp=%1
:: Из первого параметра извлекаем день без лидирующего нуля
set zdd=%zp:~,2%
set /a zdd=1%zdd% - 100

:: Извлекаем месяц без лидирующего нуля
set zmm=%zp:~3,2%
set /a zmm=1%zmm% - 100

:: Извлекаем год "минус" 2000.
set zyy=%zp:~6,4%
set /a zyy=%zyy% - 2000

:: Второй параметр - сдвиг
set zop=%2

:: На первом этапе переведем дату в количество дней с начала века (от 2000 года)
:: Количество високосных годов до текущей даты (поправка)
set /a zv=(%zyy%+3)/4

:: Дней до начала года текущей даты
set /a zr=%zyy%*365+%zv%

:: Поправка на текущий високосный год. Если год делится на 4, то 1 день.
set zt=4
set /a zt=%zyy%%%zt%
set zp=0
if %zt%==0 set zp=1

:: Дней до текущего месяца
if %zmm%==1 set zd=0
if %zmm%==2 set zd=31
if %zmm%==3 set zd=59+%zp%
if %zmm%==4 set zd=90+%zp%
if %zmm%==5 set zd=120+%zp%
if %zmm%==6 set zd=151+%zp%
if %zmm%==7 set zd=181+%zp%
if %zmm%==8 set zd=212+%zp%
if %zmm%==9 set zd=243+%zp%
if %zmm%==10 set zd=273+%zp%
if %zmm%==11 set zd=304+%zp%
if %zmm%==12 set zd=334+%zp%

:: Всего дней в текущей дате от начала века
set /a zr=%zr%+%zd%+%zdd%

:: Добавляем к количеству дней сдвиг
set /a zr=%zr%%zop%

:: На втором этапе из общего количества дней от начала века
:: ежемесячным вычитанием рассчитаем новую дату

:: Начальные значения счетчиков (день, месяц, год)
set zrd=0
set zrm=1
set zry=0

:: Начало цикла по годам
:loop
:: Поправка для февраля, если год високосный
set zt=4
set /a zt=%zry%%%zt%
set zf=28
if %zt%==0 set zf=29

:: Пробегаем весь год по месяцам
:: Для января
if %zr% LEQ 31 goto :endloop
set /a zr=%zr%-31
set /a zrm=%zrm%+1

:: Для февраля
if %zr% LEQ %zf% goto :endloop
set /a zr=%zr%-%zf%
set /a zrm=%zrm%+1

:: Для марта
if %zr% LEQ 31 goto :endloop
set /a zr=%zr%-31
set /a zrm=%zrm%+1

:: Для апреля
if %zr% LEQ 30 goto :endloop
set /a zr=%zr%-30
set /a zrm=%zrm%+1

:: Для мая
if %zr% LEQ 31 goto :endloop
set /a zr=%zr%-31
set /a zrm=%zrm%+1

:: Для июня
if %zr% LEQ 30 goto :endloop
set /a zr=%zr%-30
set /a zrm=%zrm%+1

:: Для июля
if %zr% LEQ 31 goto :endloop
set /a zr=%zr%-31
set /a zrm=%zrm%+1

:: Для августа
if %zr% LEQ 31 goto :endloop
set /a zr=%zr%-31
set /a zrm=%zrm%+1

:: Для сентября
if %zr% LEQ 30 goto :endloop
set /a zr=%zr%-30
set /a zrm=%zrm%+1

:: Для октября
if %zr% LEQ 31 goto :endloop
set /a zr=%zr%-31
set /a zrm=%zrm%+1

:: Для ноября
if %zr% LEQ 30 goto :endloop
set /a zr=%zr%-30
set /a zrm=%zrm%+1

:: Для декабря
if %zr% LEQ 31 goto :endloop
set /a zr=%zr%-31

:: Год обсчитан, обнуляем месяц, увеличиваем год
set zrm=1
set /a zry=%zry%+1
goto :loop

:endloop

:: Остаток от вычитания, меньший целого месяца - это число дней в новой дате
set zrd=%zr%

:: День с лидирующим нулем - два символа
set /a zrd=%zrd%+100
set zrd=%zrd:~1,2%

:: Месяц с лидирующим нулем - два символа
set /a zrm=%zrm%+100
set zrm=%zrm:~1,2%

:: Год - четыре символа
set /a zry=%zry%+2000

echo %zry%-%zrm%-%zrd%

Дает, например, вот такие результаты:

C:\TMP\addday 02.05.2008 +600
2009-12-23

C:\TMP\addday 23.12.2009 -600
2008-05-02

[avk2567]

set $tok=1-3
tok - временная переменная выставляемая таким образом, чтобы FOR использующий ее в качестве параметра обрабатывал нужные нам токены.
А %$tok% - это подстановка (в данном случае 1-3) где надо.